home *** CD-ROM | disk | FTP | other *** search
/ FishMarket 1.0 / FishMarket v1.0.iso / fishies / 001-025 / disk_013 / hauntedm.bas < prev    next >
BASIC Source File  |  1992-05-06  |  11KB  |  185 lines
  1. 5     SCREEN 1,3
  2. 10    GOTO 5000
  3. 20    rem COPYRIGHT (C) CLOAD 1982
  4. 50    rem JOHN OLSON
  5. 60    rem HOXIE, KS  67740
  6. 70    rem FALL, 1981
  7. 80    rem MANSION ADVENTURE
  8. 100   REM ADAPTED FOR THE AMIGA BY GARY D. WALBORN 11/3/85
  9. 120   DIM L$(25),A(4,25),M$(3,36),B(3,36)
  10. 130   scnclr:GOSUB 1770:GOSUB 1130:B=1
  11. 140   scnclr:B(1,5)=1+RND(23):B(1,6)=2+RND(22):B(1,7)=2+RND(22):PRINT"LOCATION: ";L$(B):C=0:PRINT"YOU SEE: ";:FOR A=1 TO 36
  12. 150   IF B(1,A)=B AND B(3,A)<>0 THEN PRINT TAB(10);M$(2,A):C=1
  13. 160   NEXT A:IF C=0 THEN PRINT "NOTHING OF INTEREST"
  14. 170   C=0:PRINT "DIRECTIONS: ";:IF A(1,B)<>0 THEN PRINT "NOR ";:C=1180   IF A(2,B)<>0 THEN PRINT "SOU ";:C=1
  15. 190   IF A(3,B)<>0 THEN PRINT "EAS ";:C=1
  16. 200   IF A(4,B)<>0 THEN PRINT "WES";:C=1
  17. 210   IF C=0 THEN PRINT "? ? ?";
  18. 220   PRINT:PRINT STRING$(30,"-")
  19. 230   INPUT"WHAT NOW . .";M$:PRINT" ";
  20. 240   IF M$="N" THEN M$="GO NOR" ELSE IF M$="S" THEN M$="GO SOU"
  21. 250   IF M$="E" THEN M$="GO EAS" ELSE IF M$="W" THEN M$="GO WES"
  22. 260   IF M$="LOO" OR M$="LOOK" THEN 140
  23. 270   IF LEN(M$)<3 THEN PRINT "?? WHAT ??":GOTO 230
  24. 280   N$=LEFT$(M$,3):FOR A = (LEN(M$)-2) TO 1 STEP -1:IF MID$(M$,A,1)=" " THEN 290 ELSE NEXT A
  25. 290   O$=MID$(M$,A+1,3): IF N$="INV" THEN 370 ELSE IF N$="SCO" THEN 1090
  26. 300   IF N$="HEL" THEN 410 ELSE IF N$="GO " OR N$="WAL" THEN 470
  27. 310   IF N$="LOO" OR N$="EXA" THEN 530 ELSE IF N$="GET" OR N$="TAK" THEN 590
  28. 320   IF N$="DRO" OR N$="LEA" OR N$="PUT" THEN 740 ELSE IF N$="PRY" THEN 800
  29. 330   IF N$="INS" THEN 780 ELSE IF N$="KIC" THEN 820
  30. 340   IF N$="PUS" OR N$="PUL" OR N$="MOV" THEN 850 ELSE IF N$="OPE" OR N$="UNL" THEN 940
  31. 350   IF N$="KIL" THEN 1050 ELSE IF N$="BRE" THEN 1060 ELSE IF N$="REA" THEN 1080
  32. 360   PRINT"I DON'T UNDERSTAND THE VERB !":GOTO 230
  33. 370   C=0:FOR A=1 TO 36
  34. 380   IF B(1,A)=25 THEN PRINT TAB(2);M$(2,A):C=1
  35. 390   NEXT A:IF C=0 THEN PRINT"YOU HAVE NOTHING !"
  36. 400   GOTO 230
  37. 410   IF B=1 THEN PRINT "INVENTORY AT START / SCORE AT":PRINT" THE END OF THE GAME":GOTO 230
  38. 420   IF B=7 OR B=13 OR B=18 OR B=23 OR B=24 THEN PRINT"EXAMINE THINGS . .":GOTO 230
  39. 430   IF B=4 THEN PRINT"YOU DESERVE A 'BREAK' TODAY !":GOTO 230
  40. 440   IF B=2 OR B=11 THEN PRINT"MOVE THINGS !":GOTO 230
  41. 450   IF B=5 THEN PRINT "?? EKAT ??":GOTO 230
  42. 460   PRINT "I'M AS CONFUSED AS YOU !":GOTO 230
  43. 470   IF O$="DOO" AND B=1 AND B(1,2)=1 THEN B=3:GOTO 140
  44. 480   IF O$="NOR" AND A(1,B)<>0 THEN B=A(1,B):GOTO 140
  45. 490   IF O$="SOU" AND A(2,B)<>0 THEN B=A(2,B):GOTO 140
  46. 500   IF O$="EAS" AND A(3,B)<>0 THEN B=A(3,B):GOTO 140
  47. 510   IF O$="WES" AND A(4,B)<>0 THEN B=A(4,B):GOTO 140
  48. 520   PRINT"YOU'RE UNABLE TO . . .":GOTO 230
  49. 530   FOR A=1 TO 36:IF O$=M$(1,A) THEN 550 ELSE NEXT A
  50. 540   PRINT"I DON'T UNDERSTAND THE NOUN !":GOTO 230
  51. 550   IF B(1,A)<>B AND B(1,A)<>25 THEN PRINT "IT ISN'T AROUND . .":GOTO 230
  52. 560   IF B(3,A)=0 THEN PRINT "YOU CAN'T . . YET!":GOTO 230
  53. 570   IF M$(3,A)="Z" THEN PRINT "YOU SEE NOTHING OF INTEREST!":GOTO 230
  54. 580   PRINT M$(3,A):GOTO 230
  55. 590   FOR A=1 TO 36:IF O$=M$(1,A) THEN 610 ELSE NEXT A
  56. 600   GOTO 540
  57. 610   IF B(1,A)=25 THEN PRINT "YOU ALREADY HAVE IT !":GOTO 230
  58. 620   IF B(1,A)<>B THEN PRINT "THAT ITEM ISN'T AROUND !":GOTO 230
  59. 630   IF B(2,A)=0 THEN PRINT "YOU'RE UNABLE TO . . .":GOTO 230
  60. 640   C=0:FOR D=1 TO 36:IF B(1,D)=25 THEN C=C+1
  61. 650   NEXT D:IF C>4 THEN PRINT "YOU CAN'T CARRY ANY MORE !":GOTO 230
  62. 660   IF A=21 THEN M$(3,31)="Z"
  63. 670   IF A=25 THEN M$(3,24)="Z"
  64. 680   IF A=23 THEN M$(3,22)="Z"
  65. 690   IF A=15 THEN M$(2,35)="**THE DIAMOND**"
  66. 700   IF A=35 AND LEFT$(M$(2,35),2)="**" THEN SCNCLR:PRINT "A TRAP DOOR OPENS . . .":PRINT"YOU FIND YOURSELF FALLING . . .":PRINT"FALLING . . .":GOTO 1010
  67. 710   PRINT "O.K.  . . YOU'VE GOT IT !":B(1,A)=25:B(3,A)=1
  68. 720   IF A=16 AND B(3,17)=0 THEN B(3,17)=1:PRINT "A TOKEN WAS UNDER THE RUG . ."
  69. 730   GOTO 230
  70. 740   FOR A=1 TO 36:IF O$=M$(1,A) THEN 760 ELSE NEXT A
  71. 750   GOTO 540760   IF B(1,A)<>25 THEN PRINT "YOU DON'T HAVE THAT ITEM !":GOTO 230
  72. 770   PRINT"O.K.  . .  YOU'VE DROPPED IT !":B(1,A)=B:GOTO 230
  73. 780   IF B=24 AND O$="KEY" AND B(1,15)=25 THEN PRINT"O.K.":B(1,15)=24:M$(2,35)=">>THE DIAMOND<<":GOTO 230
  74. 790   PRINT"SORRY, THAT'S NOT POSSIBLE !":GOTO 230
  75. 800   IF O$="DOO" AND B=1 AND B(1,1)=1 THEN B(1,1)=0:M$(1,1)="!":B(1,2)=1:PRINT"THE DOOR POPS OPEN . .":GOTO 230
  76. 810   PRINT"THAT'S NOT POSSIBLE . . SORRY!":GOTO 230
  77. 820   IF B<>12 OR O$<>"DES" THEN PRINT "NOTHING HAPPENS . .":GOTO 230
  78. 830   PRINT"  ALL OF A SUDDEN . .":PRINT"  YOU FIND YOURSELF FALLING . .":PRINT"  THRU A SECRET ENTRANCE . ."
  79. 840   FOR A=1 TO 1500:NEXT A:B=14:GOTO 140
  80. 850   IF B<>11 THEN 870 ELSE IF O$="FOU" AND B(1,31)=0 THEN PRINT "A SMALL COMPARTMENT OPENS ! !":B(1,31)=11:B(1,21)=11:GOTO 230
  81. 860   PRINT"NOTHING HAPPENS !":GOTO 230
  82. 870   IF B=2 AND O$="CAB" AND B(1,12)=0 THEN PRINT "YOU SEE A SAFE !":B(1,12)=2:GOTO 230
  83. 880   IF B=18 AND O$="LEV" THEN SCNCLR:PRINT"THERE IS AN EXPLOSION . . .":GOTO 1010
  84. 890   IF B=23 AND O$="BUT" THEN SCNCLR:PRINT"THE PASSAGE BEGINS TO FLOOD . .":GOTO 1010
  85. 900   FOR A=1 TO 36:IF O$=M$(1,A) THEN 920 ELSE NEXT A
  86. 910   GOTO 540
  87. 920   IF B(1,A)<>B AND B(1,A)<>25 THEN PRINT"THAT ITEM ISN'T AROUND":GOTO 230
  88. 930   PRINT"O.K. . . NOTHING HAPPENS !":GOTO 230
  89. 940   IF B<>2 OR O$<>"SAF" OR B(1,12)<>2 THEN 1040
  90. 950   PRINT" TO  OPEN  THE SAFE  YOU  MUST":PRINT" USE AND ENTER A  THREE  NUMBER"
  91. 960   PRINT" COMBINATION.   ENTER  IT  WITH":PRINT" SLASHES BETWEEN THE  THREE #'S"
  92. 970   PRINT" YOU WISH TO USE.  FOR EXAMPLE:":PRINT" 27/14/82  . . . . IF YOU THINK"
  93. 980   PRINT" THE COMBINATION IS 27, 14, 82."
  94. 990   INPUT" YOUR ATTEMPT . .";M$: IF M$="13/82/30" THEN 1020
  95. 1000  SCNCLR:PRINT"THERE IS AN EXPLOSION . .":PRINT:PRINT"THAT WAS THE WRONG COMBINATION!"
  96. 1010  PRINT:PRINT "Y O U   A R E   D E A D !":PRINT:INPUT"HIT ENTER TO RESTART";M$
  97. 1020  PRINT" THE SAFE POPS OPEN . . .":PRINT" TWO ITEMS FALL TO THE FLOOR !"
  98. 1030  B(1,12)=0:B(1,13)=2:B(1,14)=2:B(1,15)=2:M$(1,12)="q":GOTO 230
  99. 1040  PRINT"SORRY, THAT'S NOT POSSIBLE !":GOTO 230
  100. 1050  PRINT"THOU SHALT NOT . .":GOTO 230
  101. 1060  IF (B(1,30)=25 OR B(1,30)=B) AND O$="STA" THEN PRINT"IT BREAKS INTO 5,378 PIECES -":PRINT" REVEALING A MEDALLION !":B(1,30)=0:B(1,10)=B:GOTO 230
  102. 1070  PRINT"SORRY, THAT'S NOT POSSIBLE !":GOTO 230
  103. 1080  PRINT"TELL ME TO 'LOOK' OBJECT . .":PRINT"THEN YOU READ . . .":GOTO 230
  104. 1090  IF B(1,35)=25 OR B(1,35)=1 THEN 1110
  105. 1100  PRINT"AT THE MOMENT: SCORE OF ZERO !":GOTO 230
  106. 1110  IF B<>1 THEN PRINT"YOU MUST BE OUTSIDE TO SCORE !":GOTO 230
  107. 1120  SCNCLR:PRINT" C O N G R A T U L A T I O N S !":PRINT:PRINT" YOU HAVE WON !":PRINT:END
  108. 1130  FOR A=1 TO 25:READ L$(A),A(1,A),A(2,A),A(3,A),A(4,A):NEXT A
  109. 1140  DATA"OUTSIDE THE MANSION",0,0,0,0
  110. 1150  DATA"A LIBRARY",0,0,3,0
  111. 1160  DATA"AN ENTRANCE HALL",6,1,4,2
  112. 1170  DATA"A SITTING ROOM",7,0,0,3
  113. 1180  DATA"A SMALL BEDROOM",0,0,6,0
  114. 1190  DATA"A CORRIDOR",9,3,0,5
  115. 1200  DATA"A DINING ROOM",10,4,0,0
  116. 1210  DATA"A LARGE BEDROOM",11,0,9,0
  117. 1220  DATA"A CORRIDOR",12,6,10,8
  118. 1230  DATA"A KITCHEN",13,7,0,9
  119. 1240  DATA"A CLOSET",0,8,0,0
  120. 1250  DATA"A DEN",0,9,0,0
  121. 1260  DATA"A PANTRY",0,10,0,0
  122. 1270  DATA"A SECRET PASSAGE",15,12,0,0
  123. 1280  DATA"A PASSAGE",0,14,20,16
  124. 1290  DATA"IN A PASSAGE",17,0,15,0
  125. 1300  DATA"A PASSAGE",18,16,19,0
  126. 1310  DATA"A SMALL ROOM",0,17,0,0
  127. 1320  DATA"A PASSAGE TURN",0,20,21,17
  128. 1330  DATA"A MAZE-LIKE PASSAGE",19,0,0,15
  129. 1340  DATA"A TURN IN THE PASSAGE",0,22,0,19
  130. 1350  DATA"LOST IN A PASSAGE",21,23,0,20
  131. 1360  DATA"A CONFUSING PASSAGE",22,24,0,0
  132. 1370  DATA"A TREASURE ROOM",23,0,0,0
  133. 1380  DATA"YOU",0,0,0,0
  134. 1390  FOR A=1 TO 36:READ M$(1,A),M$(2,A),M$(3,A),B(1,A),B(2,A),B(3,A):NEXT A
  135. 1400  DATA"DOO","A LOCKED DOOR","IT APPEARS SOLID!",1,0,1
  136. 1410  DATA"DOO","AN OPEN DOOR","Z",0,0,1
  137. 1420  DATA"BAR","A METAL BAR","WRITING: 4.U.2. PRY",25,1,1
  138. 1430  DATA"PAP","A SHEET OF PAPER","WRITING: SAFE COMBO/ATOMIC #'S",25,1,1
  139. 1440  DATA"MOU","A MOUSE","IT IS WATCHING YOU !",3,0,1
  140. 1450  DATA"SPI","A LARGE SPIDER","IT APPEARS DANGEROUS!",10,0,1
  141. 1460  DATA"COB","COBWEBS . . .","Z",7,0,1
  142. 1470  DATA"TRE","A COAT TREE","WRITING: I WAS ONCE AN OAK!",3,1,1
  143. 1480  DATA"SOF","A SHABBY SOFA","Z",4,0,1
  144. 1490  DATA"MED","A LEAD MEDALLION","WRITING:  LEAD A# 82",0,1,1
  145. 1500  DATA"CAB","A DINGY CABINET","IT IS EMPTY . . .",2,0,1
  146. 1510  DATA"SAF","A LOCKED SAFE","WRITING: VERYSTRONG CO.",0,0,1
  147. 1520  DATA"SAF","AN OPEN SAFE","Z",0,0,1
  148. 1530  DATA"NOT","A NOTEBOOK","WRITING:  KSED KCIK",0,1,1
  149. 1540  DATA"KEY","A SMALL KEY","WRITING: INSERT",0,1,1
  150. 1550  DATA"RUG","A TATTERED RUG","Z",5,1,1
  151. 1560  DATA"TOK","A ZINC TOKEN","WRITING:  ZINC A# 30",5,1,0
  152. 1570  DATA"TAB","AN OLD TABLE","CARVED ON IT: OTKK ENTQ",7,0,1
  153. 1580  DATA"DRE","A RUN-DOWN DRESSER","IT IS EMPTY . .",8,0,1
  154. 1590  DATA"HOO","WALL HOOKS (1 TO 4)","Z",11,0,1
  155. 1600  DATA"COI","AN ALUMINUM COIN","WRITING: ALUMINUM A# 13",0,1,0
  156. 1610  DATA"COU","A COUNTER","YOU SEE A KNIFE ON IT !",10,0,1
  157. 1620  DATA"KNI","A KNIFE","WRITING: TV WONDERBLADE",10,1,0
  158. 1630  DATA"SHE","A SET OF SHELVES","YOU SEE A FLASHLIGHT !",13,0,1
  159. 1640  DATA"FLA","A FLASHLIGHT","IMPRINTED: NEVEREADY CO.",13,1,0
  160. 1650  DATA"BUC","AN EMPTY BUCKET","WRITING: EL-CHEAPO PLASTIC CO.",13,1,1
  161. 1660  DATA"WAT","A WATCH","WRITING: TIME FOR COFFEE !",15,1,1
  162. 1670  DATA"FIL","A NAIL FILE","Z",20,1,1
  163. 1680  DATA"DES","A DESK","IT IS IN POOR CONDITION !",12,0,1
  164. 1690  DATA"STA","A CHEAP STATUE","IMPRINTED: MADE IN JAPAN",4,1,1
  165. 1700  DATA"COM","A SMALL COMPARTMENT","YOU SEE: AN ALUMINUM COIN",0,0,1
  166. 1710  DATA"LEV","A BLACK LEVER","WRITING: EP OPU QVMM",18,0,1
  167. 1720  DATA"BUT","A RED BUTTON","WRITING: EFBUI !",23,0,1
  168. 1730  DATA"SLO","A KEY SIZE SLOT","WRITING: HMRDQS JDX EHQRS",24,0,1
  169. 1740  DATA"DIA","**A DIAMOND**","IT IS FLAWLESS . . HUGE !",24,1,1
  170. 1750  DATA"SIG","A SIGN","ADVENTURES ARE FUN ! ?",14,0,1
  171. 1760  INPUT" HIT ENTER TO START . . READY";M$:RETURN
  172. 1770  PRINT "M A N S I O N":PRINT
  173. 1780  PRINT" SOME SAY  IT'S HAUNTED . . . .":PRINT" OTHERS SAY IT'S CURSED . . . ."
  174. 1790  PRINT" WHATEVER THE TRUTH . . . . . .":PRINT" NO ONE  HAS EVER RECOVERED THE"
  175. 1800  PRINT" FABLED MANSION DIAMOND ! !":PRINT
  176. 1810  PRINT" YOUR TASK IS TO ENTER THE MAN-":PRINT" SION,  FIND THE  DIAMOND,  AND":PRINT" THEN GET OUT SAFELY."
  177. 1820  PRINT:INPUT" HIT ENTER . . . TO CONTINUE";O$
  178. 1830  SCNCLR:PRINT:PRINT" MAKE YOUR QUEST  USING  ONE OR":PRINT" TWO WORD COMMANDS,SUCH AS:"
  179. 1840  PRINT:PRINT" LOOK,  GO NORTH,  TAKE STATUE,":PRINT" BREAK STATUE, HELP, INVENTORY,"
  180. 1850  PRINT" LOOK CABINET, ETC.":PRINT
  181. 1860  PRINT" IF ONE COMMAND  DOESN'T  WORK,":PRINT" THEN TRY ANOTHER.":PRINT
  182. 1870  PRINT"     G O O D   L U C K ! !":PRINT:RETURN
  183. 5000  GOTO 100
  184.